VERSION 5.00
Begin VB.Form Test_Type_mtnc 
   BorderStyle     =   3  'Fixed Dialog
   ClientHeight    =   1725
   ClientLeft      =   1905
   ClientTop       =   2745
   ClientWidth     =   5445
   ControlBox      =   0   'False
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   PaletteMode     =   1  'UseZOrder
   ScaleHeight     =   1725
   ScaleWidth      =   5445
   ShowInTaskbar   =   0   'False
   Begin VB.CommandButton SSC_dropped 
      Height          =   276
      Left            =   2880
      Style           =   1  'Graphical
      TabIndex        =   3
      Top             =   1260
      Width           =   252
   End
   Begin VB.CommandButton spp_save 
      Default         =   -1  'True
      Height          =   612
      Left            =   4020
      Style           =   1  'Graphical
      TabIndex        =   4
      Top             =   960
      Width           =   612
   End
   Begin VB.CommandButton ssp_quit 
      Height          =   612
      Left            =   4680
      Style           =   1  'Graphical
      TabIndex        =   5
      Top             =   960
      Width           =   612
   End
   Begin VB.ComboBox cbo_Category2 
      Height          =   288
      Left            =   1380
      Style           =   2  'Dropdown List
      TabIndex        =   11
      TabStop         =   0   'False
      Top             =   420
      Visible         =   0   'False
      Width           =   390
   End
   Begin VB.CheckBox chk_Int 
      Caption         =   "Check1"
      Height          =   252
      Left            =   1680
      TabIndex        =   2
      Top             =   900
      Width           =   252
   End
   Begin VB.TextBox txt_dropped 
      ForeColor       =   &H00FF0000&
      Height          =   288
      Left            =   1680
      Locked          =   -1  'True
      TabIndex        =   8
      TabStop         =   0   'False
      Top             =   1260
      Width           =   1212
   End
   Begin VB.TextBox Txt_desc 
      Height          =   285
      Left            =   2160
      MaxLength       =   80
      TabIndex        =   1
      Top             =   420
      Width           =   3135
   End
   Begin VB.ComboBox cbo_Category 
      Height          =   288
      Left            =   120
      Style           =   2  'Dropdown List
      TabIndex        =   0
      Top             =   420
      Width           =   1812
   End
   Begin VB.Label lbl_Drop 
      Caption         =   "Drop date"
      BeginProperty Font 
         Name            =   "MS Sans Serif"
         Size            =   8.25
         Charset         =   0
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      Height          =   252
      Left            =   120
      TabIndex        =   10
      Top             =   1260
      Width           =   1452
   End
   Begin VB.Label lbl_Int 
      Caption         =   "Internet flag"
      BeginProperty Font 
         Name            =   "MS Sans Serif"
         Size            =   8.25
         Charset         =   0
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      Height          =   252
      Left            =   120
      TabIndex        =   9
      Top             =   900
      Width           =   1452
   End
   Begin VB.Label lbl_Desc 
      Alignment       =   2  'Center
      Caption         =   "Description"
      BeginProperty Font 
         Name            =   "MS Sans Serif"
         Size            =   8.25
         Charset         =   0
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      Height          =   252
      Left            =   2160
      TabIndex        =   7
      Top             =   120
      Width           =   3132
   End
   Begin VB.Label lbl_Categ 
      Alignment       =   2  'Center
      Caption         =   "Category"
      BeginProperty Font 
         Name            =   "MS Sans Serif"
         Size            =   8.25
         Charset         =   0
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      Height          =   252
      Left            =   120
      TabIndex        =   6
      Top             =   120
      Width           =   1812
   End
End
Attribute VB_Name = "Test_Type_mtnc"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Dim mb_CategNotLoaded As Boolean
Private Sub Cbo_category_DropDown()

Dim ls_Categ As String

MouseOff
If mb_CategNotLoaded Then
    mb_CategNotLoaded = KO
    If cbo_Category.ListIndex <> -1 Then
        ls_Categ = cbo_Category2.List(cbo_Category.ListIndex)
    Else
        ls_Categ = ""
    End If
    cbo_Category2.Clear
    cbo_Category.Clear
    FillCbo "Test_Category2", cbo_Category2, cbo_Category
    If ls_Categ <> "" Then
        cbo_Category.ListIndex = ComboFindItem(cbo_Category2, ls_Categ)
    End If
End If
MouseOn

End Sub

Private Sub Form_Load()

On Error GoTo suite

MouseOff

If gl_CodePage <> 1252 And gl_CodePage <> 0 Then ChangeCharset Me

spp_save.Picture = LoadResPicture(RES_OK, 1)
ssp_quit.Picture = LoadResPicture(RES_QUIT, 1)
SSC_dropped.Picture = LoadResPicture(RES_DOWN2, vbResIcon)

Getcsts
Select Case gs_Action
Case "Add"
    mb_CategNotLoaded = OK
Case "Update"
    cbo_Category.Enabled = KO
    cbo_Category.AddItem gs_TableCode2
    cbo_Category2.AddItem gs_TableCode
    cbo_Category.ListIndex = 0
    Txt_desc = gs_TableCode5
    If gs_TableCode6 = "X" Then
        chk_Int.value = 1
    End If
    txt_dropped = gs_TableCode7
Case "Delete"
    cbo_Category.Enabled = KO
    Txt_desc.Enabled = KO
    chk_Int.Enabled = KO
    SSC_dropped.Visible = KO
    cbo_Category.AddItem gs_TableCode2
    cbo_Category.ListIndex = 0
    Txt_desc = gs_TableCode5
    If gs_TableCode6 = "X" Then
        chk_Int.value = 1
    End If
    txt_dropped = gs_TableCode7
'start change
'used on double click on C_Main
Case "MoreInfo"
    cbo_Category.Enabled = KO
    Txt_desc.Enabled = KO
    chk_Int.Enabled = KO
    SSC_dropped.Visible = KO
    cbo_Category.AddItem gs_TableCode2
    cbo_Category.ListIndex = 0
    Txt_desc = gs_TableCode5
    If gs_TableCode6 = "X" Then
        chk_Int.value = 1
    End If
    txt_dropped = gs_TableCode7
    spp_save.Visible = KO
'end change
End Select
MouseOn
Exit Sub

suite:
StdError
End Sub

Private Sub spp_save_Click()

On Error GoTo suite

MouseOff
gb_Return = OK
Select Case gs_Action
Case "Add"
    If AddTable Then
        Txt_desc = ""
        cbo_Category.ListIndex = -1
        chk_Int.value = 0
        txt_dropped = ""
        If gl_NbLineDisplay < 2 Then
            C_main.FillGrid
        End If
        Txt_desc.SetFocus
      End If
Case "Update"
    If UpdTable Then
        Unload Me
    End If
Case "Delete"
    If DltTable Then
        Unload Me
    End If
End Select
MouseOn
Exit Sub

suite:
MouseOn
StdError
End Sub
Private Sub SSC_dropped_Click()

MouseOff
gb_Return = KO
gs_Date = txt_dropped
Dates.show 1
If gb_Return Then
    txt_dropped = gs_Date
End If
MouseOn

End Sub
Private Sub ssp_quit_Click()

MouseOff
Unload Me

End Sub
Private Function UpdTable() As Boolean

Dim ls_Req As String
Dim ll_Statement As Long
Dim li_Status As Integer
Dim ll_lngrows As Long
Dim ls_Line As String
Dim ls_IntFlag As String
Dim ls_DropFlag As String
Dim ls_DropDate As String

UpdTable = KO

On Error GoTo suite

If Control Then
    If chk_Int.value = 1 Then ls_IntFlag = "X"
    If txt_dropped <> "" Then
        ls_DropFlag = "X"
        ls_DropDate = FormatD(txt_dropped, "mm/dd/yyyy")
    End If
    ls_Req = "EXEC Test_Type_upd " _
     & gs_TableCode3 & ", '" _
     & QuoteParam(Txt_desc) & "', " _
     & cbo_Category2.List(cbo_Category.ListIndex) & ", '" _
     & ls_IntFlag & "', '" _
     & ls_DropFlag & "', '" _
     & ls_DropDate & "', " _
     & gs_TableCode4
    If SQLSubmit(gl_Environment, gl_Database, ll_Statement, ls_Req) Then
        li_Status = SQLRowCount(ll_Statement, ll_lngrows)
        li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
        If ll_lngrows = 0 Then
            SendMessage 2, "Another user change the record", gut_LangLogin.Code
            C_main.FillGrid
        Else
            UpdTable = OK
            C_main.Grid.RemoveItem C_main.Grid.Row
            ls_Line = cbo_Category2.List(cbo_Category.ListIndex) & Chr(9) & cbo_Category & Chr(9) & gs_TableCode3 & Chr(9) & CInt(gs_TableCode4) + 1 & Chr(9) & Txt_desc & Chr(9) & ls_IntFlag & Chr(9) & txt_dropped
            C_main.Grid.AddItem ls_Line, C_main.Grid.Row
        End If
    Else
        li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
        SendMessage 3, "Update failed", gut_LangLogin.Code
    End If
End If
Exit Function

suite:
Select Case Err
Case 30015
    C_main.FillGrid
Case Else
    li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
    StdError
End Select
End Function
Private Function AddTable() As Boolean

Dim ls_Req As String
Dim ll_Statement As Long
Dim li_Status As Integer
Dim ll_lngrows As Long
Dim ls_Code As String
Dim ls_Line As String
Dim ls_IntFlag As String
Dim ls_DropFlag As String
Dim ls_DropDate As String

AddTable = KO

On Error GoTo suite

If Control Then
    If chk_Int.value = 1 Then ls_IntFlag = "X"
    If txt_dropped <> "" Then
        ls_DropFlag = "X"
        ls_DropDate = FormatD(txt_dropped, "mm/dd/yyyy")
    End If
    ls_Req = "EXEC Test_Type_ins '" _
     & QuoteParam(Txt_desc) & "', " _
     & cbo_Category2.List(cbo_Category.ListIndex) & ", '" _
     & ls_IntFlag & "','" _
     & ls_DropFlag & "','" _
     & ls_DropDate & "'"
    If SQLSubmit(gl_Environment, gl_Database, ll_Statement, ls_Req) Then
        li_Status = SQLRowCount(ll_Statement, ll_lngrows)
        If ll_lngrows = 0 Then
            li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
            SendMessage 4, "Insert failed", gut_LangLogin.Code
            C_main.FillGrid
        Else
            AddTable = OK
            li_Status = SQLFetch(ll_Statement)
            If li_Status = SQL_SUCCESS Or li_Status = SQL_SUCCESS_WITH_INFO Then
                ls_Code = ODBCData(ll_Statement, 1)
                li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
                ls_Line = cbo_Category2.List(cbo_Category.ListIndex) & Chr(9) & cbo_Category & Chr(9) & ls_Code & Chr(9) & 1 & Chr(9) & Txt_desc & Chr(9) & ls_IntFlag & Chr(9) & txt_dropped
                C_main.Grid.AddItem ls_Line
                C_main.Grid.Row = C_main.Grid.Rows - 1
            Else
                li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
                C_main.FillGrid
            End If
        End If
    Else
        li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
        SendMessage 4, "Insert failed", gut_LangLogin.Code
    End If
End If
Exit Function

suite:
li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
StdError
End Function
Private Function DltTable() As Boolean

Dim ls_Req As String
Dim ll_Statement As Long
Dim li_Status As Integer
Dim ll_lngrows As Long

DltTable = KO

On Error GoTo suite

MouseOn
If SendMessage(5, "Delete record ?", gut_LangLogin.Code, vbQuestion + vbYesNo, "Delete ") = vbYes Then
    MouseOff
    ls_Req = "EXEC Test_Type_del " _
     & gs_TableCode3 & ", " _
     & gs_TableCode4
    If SQLSubmit(gl_Environment, gl_Database, ll_Statement, ls_Req) Then
        li_Status = SQLRowCount(ll_Statement, ll_lngrows)
        li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
        If ll_lngrows = 0 Then
            SendMessage 7, "Delete failed : concurrency problem ?", gut_LangLogin.Code
            C_main.FillGrid
        Else
            DltTable = OK
            C_main.Grid.RemoveItem C_main.Grid.Row
        End If
    Else
        li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
        SendMessage 6, "Delete failed", gut_LangLogin.Code
    End If
End If
MouseOff
Exit Function

suite:
Select Case Err
Case 30015
    C_main.FillGrid
Case Else
    li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
    StdError
End Select
End Function
Private Sub Getcsts()

Dim ls_Req As String
Dim ll_Statement As Long
Dim li_Status As Integer
Dim ls_Field As String, ls_Text As String

On Error GoTo suite

ls_Req = "EXEC Screen_Csts 'mtnc_Test_Type', '" & gut_LangLogin.Code & "'"

If SQLSubmit(gl_Environment, gl_Database, ll_Statement, ls_Req) Then
    li_Status = SQL_SUCCESS
Else
    li_Status = SQL_ERROR
End If
Do While li_Status = SQL_SUCCESS Or li_Status = SQL_SUCCESS_WITH_INFO
    li_Status = SQLFetch(ll_Statement)
    If li_Status = SQL_SUCCESS Or li_Status = SQL_SUCCESS_WITH_INFO Then
        ls_Field = ODBCData(ll_Statement, 1)
        ls_Text = left(ODBCData(ll_Statement, 2), 30)
        Select Case ls_Field
        Case "title": Caption = ls_Text
        Case "titleA": If gs_Action = "Add" Then Caption = Caption & " - " & ls_Text
        Case "titleU": If gs_Action = "Update" Then Caption = Caption & " - " & ls_Text
        Case "titleD": If gs_Action = "Delete" Then Caption = Caption & " - " & ls_Text
        Case "lbl_Desc": lbl_Desc = ls_Text
        Case "lbl_Categ": lbl_Categ = ls_Text
        Case "lbl_Int": lbl_Int = ls_Text
        Case "lbl_Drop": lbl_Drop = ls_Text
        End Select
    End If
Loop
li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
Exit Sub

suite:
li_Status = SQLFreeStatement(ll_Statement, SQL_DROP)
StdError
End Sub
Private Function Control() As Boolean

Control = KO
If cbo_Category = "" Then
    cbo_Category.SetFocus
    SendMessage 8, "Value must be filled in", gut_LangLogin.Code
    Exit Function
End If
'/* start modif */
If (Txt_desc.Text = "") And (gs_TableName <> "Test_Type") Then
    Txt_desc.SetFocus
    SendMessage 8, "Value must be filled in", gut_LangLogin.Code
    Exit Function
End If
'/* end modif */
Control = OK

End Function
